/**********************************************************************
 **  小鹏浇花系统
 * 
 **  version: 1.0.0
 **  author: 老张
 **  homesite: www.xpstem.com/product/intelligent-watering/index
 **********************************************************************/
#include <Arduino.h>
#include <SSD1306Wire.h>    // 4.6.1 (ThingPulse)
#include <OneButton.h>      // 2.6.1
#include <ArrayList.h>      // 1.0.2

//************** 常数数据 开始 **********************
// Pins
int soil_moisture_sensor_pin = 27;      // 土壤湿度传感器引脚
int pump_control_relay_pin = 15;        // 水泵继电器引脚
int oled_display_pin_scl = 22;          // OLED显示屏I2C引脚
int oled_display_pin_sda = 21;          // OLED显示屏I2C引脚
int oled_display_i2c_addr = 61;         // OLED显示屏I2C地址
int manual_button_pin = 26;             // 手动按钮引脚

//************* 配置变量 结束 *********************

//************* 运行时变量 开始 ********************
OneButton manualBtn(manual_button_pin, true);

int stateCode = 0; //1:config, 2:work, 3:sleep, 9:error
String stateInfo = "";

int collectCount = 0;
int sensorVal = 0;
int Threshold = 50;  // 湿度阀值

ArrayList<int> valueList; // 湿度值列表

QueueHandle_t msgQueue = xQueueCreate(10, sizeof(int)); // 消息队列

//************* 运行时变量 结束 *********************

/***********************************************************
 ***  控制水泵继电器
 **********************************************************/ 
void main_watering(int relayPin, int seconds) {
  pinMode(relayPin, OUTPUT);
  
  digitalWrite(relayPin, HIGH);
  Serial.printf("打开水泵继电器，引脚：%d，保持 %d 秒。\n", relayPin, seconds);
  
  for (int i=0; i<seconds; i++) { 
    Serial.print("."); 
    delay(1000);
  }
  Serial.println("");
        
  digitalWrite(relayPin, LOW);
  Serial.println("关闭水泵继电器。");
}

/***********************************************************
 ***  UI任务
 **********************************************************/
void task_display(void *pvParam) {

  SSD1306Wire display(/* address */ oled_display_i2c_addr, 
    /* sda */ oled_display_pin_sda, 
    /* scl */ oled_display_pin_scl); 

  display.init();
  //display.flipScreenVertically();
  display.setFont(ArialMT_Plain_16);
  
  while(1) {
    display.clear();
    if (stateCode==1) {
      display.drawString(0, 0, "[config]");
      
    } else if (stateCode==2) {
      display.drawString(0, 0, "[work]" );
      display.drawString(0, 20, "value: " + (sensorVal==0 ? "" : String(sensorVal)) );
      if (stateInfo.length()>0) {
        display.drawString(0, 40, stateInfo );
      }
      
    } else if (stateCode==3) {
      display.drawString(0, 0, "Zzz..." );
      
    } else if (stateCode==9) {
      display.drawString(0, 0, "[error]");
      display.drawString(0, 20, stateInfo );
    }
    display.display();
    
    vTaskDelay(1000 / portTICK_PERIOD_MS);
  };
}

/******************************************************** 
 ***  Button任务
 ********************************************************/
void task_buttonTick(void *pvParam) {
  while(1) {
    manualBtn.tick();
    vTaskDelay(10 / portTICK_PERIOD_MS); //10ms
  }
}

/******************************************************** 
 ***  数据接收任务
 ********************************************************/
void task_dataReceive(void *pvParam) {
  while (1) {
    int received;
    // 从队列接收数据
    if (xQueueReceive(msgQueue, &received, 100/portTICK_PERIOD_MS) == pdTRUE) {
      valueList.add(received);

      int flag = 0;
      if (valueList.size() > 5) {
        // 检查是否全部低于阀值
        for (int i=0; i<valueList.size(); i++) {
          if (valueList.get(i) > Threshold) { // 超过阀值
            flag = 1;
            break;
          }
        }

        if (flag == 0) {
          // 全部低于阀值，则浇水一次
          main_watering(pump_control_relay_pin, 5);
        }
        
        valueList.remove(0);
      }

    }
  }
}

/***********************************************************
 ***  进入休眠状态
 **********************************************************/
void main_deepSleep(int sleepSeconds) {
  stateCode = 3;
  delay(3000); //3s for ui update
  
  //digitalWrite(power_led_pin, LOW);

  Serial.printf("进入深度休眠状态(%d%s)。\n", 
    sleepSeconds<3600 ? sleepSeconds/60 : sleepSeconds/3600,
    sleepSeconds<3600 ? "分钟" : "小时");
  ESP.deepSleep(sleepSeconds * 1e6);
}

/***********************************************************
 ***  收集传感器数据
 **********************************************************/
void main_collectData(int sensorPin) {
  Serial.printf("获取土壤湿度数据，引脚：%d\n", sensorPin);
  int originVal = analogRead(sensorPin);
  if (originVal > 0) {
    sensorVal = map(originVal, 1, 4095, 100, 1);
    // 加入队列
    xQueueSend(msgQueue, &sensorVal, portMAX_DELAY);
    
  } else { 
    // 数据无效，不做处理。
  }
}

/***********************************************************
 ***  初始化设置
 **********************************************************/
void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.println("-------------------------------");
  Serial.println("--------- 小鹏浇花系统 ----------");
  Serial.println("-------------------------------");

  Serial.println("启动UI任务程序。");
  // UI任务
  xTaskCreate(
    task_display,     // 任务函数
    "Display_Task",  // 任务名称
    4096,       // 堆栈大小(字节)
    NULL,       // 参数
    1,          // 优先级
    NULL        // 任务句柄
  );

  Serial.println("启动主程序。");
  
  stateCode = 2;

  // 等传感器稳定。
  Serial.print("等待传感器初始化(3sec).");
  for (int i=0;i<6;i++) {
    Serial.print(".");
    delay(500);
  }
  Serial.println("");

  // 手动按钮
  manualBtn.attachDoubleClick([]() {
    main_watering(pump_control_relay_pin, 5);
  });
  
  xTaskCreate(task_buttonTick, "ButtonTick_Task", 2048, NULL, 1, NULL);
  
  xTaskCreate(task_dataReceive, "DataReceive_Task", 2048, NULL, 1, NULL);
}

/***********************************************************
 ***  主循环
 ***  1.获取传感器数据并发送
 **********************************************************/
void loop() {

  // 采集数据
  main_collectData(soil_moisture_sensor_pin);
  collectCount++;
  
  vTaskDelay(120000 / portTICK_PERIOD_MS); //120s

  if (collectCount > 30) {
    main_deepSleep(23 * 3600); //23小时
  }
  
}