Arduino UNO R3的主处理器ATMega328P上有3个8位的输入/输出端口，分别是PB，PC和PD。Arduino IDE提供的Blink示例可以帮助我们了解端口的数字输出功能：

// Blink.ino
int led = 13;

void setup() {
   pinMode(led, OUTPUT);
}
 
void loop() {
   digitalWrite(led, HIGH);
   delay(1000);
   digitalWrite(led, LOW);
   delay(1000);
}

  这个示例使Arduino开发板13（PB5）引脚上的LED闪烁，与数字输出相关的Arduino库函数有：

  pinMode(pin, mode)：配置指定引脚为输入或输出

  pin：指定引脚

  mode：OUTPUT（输出），INPUT（输入）或INPUT_PULLUP（带上拉电阻的输入）

  digitalWrite(pin, value)：从指定引脚输出电平

  pin：指定引脚

  value：LOW（低电平，0V），HIGH（高电平，5V）

  ATMega328P的每个端口都由3个相关寄存器控制，方向寄存器DDRx（x = B, C, D）用于指定端口引脚方向，若向其中某位写入1，则该位控制的引脚被设置为输出，写入0则为输入。输出寄存器PORTx（x = B, C, D）在该端口引脚被设置为输出时，写入1则输出高电平，写入0则输出低电平；在该端口引脚被设置为输入时，写入1则对其启用上拉电阻，即在该端口引脚被悬空时默认输入高电平。输入寄存器PINx（x = B, C, D）在端口引脚被设置为输入时存储该端口引脚的输入，若端口引脚输入高电平，则寄存器相应位被置为1，输入低电平则置为0。

  通过直接访问寄存器改写以上程序为：

// Blink_reg.ino
void setup() {
  DDRB |= (1 << PB5);
}

void loop() {
  PORTB ^= (1 << PB5);
  delay(1000);
}

  如图所示连接电路，使按键的的两端分别连接在Arduino开发板2（PD2）引脚和GND（地）引脚上：

  这样使得按键在没有按下时2（PD2）引脚处于悬空状态，因此需要将2（PD2）引脚设置为带上拉电阻的输入模式。下面的示例使得按键在按下时13（PB5）引脚上的LED点亮，按键松开时LED熄灭：

// DigitalInputPullup.ino
void setup() {
   pinMode(2, INPUT_PULLUP);
   pinMode(13, OUTPUT);
}
 
void loop(){
   int seneorVal = digitalRead(2);
 
   if (sensorVal == HIGH) {
     digitalWrite(13, LOW);
   }
   else {
     digitalWrite(13, HIGH); 
   }
}

  除了pinMode()函数外，与数字输入相关的Arduino库函数有：

  digitalRead(pin)：从指定引脚上读取电平

  pin：指定引脚

  函数返回LOW（低电平，0V）或HIGH（高电平，5V）

  通过直接访问寄存器改写以上程序为：

// DigitalInputPullup_reg.ino
void setup() {
   DDRB |= (1 << PB5);
   DDRD &= ~(1 << PD2);
   PORTD |= (1 << PD2);
}

void loop() {
   if (PIND & (1 << PD2)) {
     PORTB &= ~(1 << PB5);
   } else {
     PORTB |= (1 << PB5);
   }
}